【MQL4学习】AGICNUMBER: 定单的“魔法“识别符

量子量化

1. 历史

在МТ3中,开仓的管理是非常费时的。交易者在处理开仓和平仓列表时，设置执行的工具是限定的。在区分“自己”和“他人”仓位时，方法非常复杂。在 МТ4中，状况有了明显的改变。现在，交易者可以使用多种函数来管理开仓，挂单并且获取平仓信息。

以MagicNumber命名的特殊参数被添加到定单识别符中。这个参数就是我们文章中将提及到的主题。

2.什么是 MagicNumber?

MQL4 参考:

1. int OrderSend( string symbol, int cmd, double volume, double price, int slippage, double stoploss, double takeprofit, string comment=NULL, int magic=0, datetime expiration=0, color arrow_color=CLR_NONE)
   
2. …
   
3. magic - 定单魔法数字。可以使用指定识别符。

复制代码

即，当定单被放置时，可以给定单指定独有的数字。这个数字将用于区分其他定单。当手动交易时，不使用（尽可能）这个特性，但是在智能交易（自动交易）运作时，此特性是不可替代的。

范例1: 在客户端内交易者和智能交易同时运行。
任务: 智能交易的运行必须按照它自己的形式计算，对于手动开仓不会干涉。
解决: 开仓的智能交易必须指定独特的MagicNumber（零除外）。接下来的日子里，智能交易只会管理提前设定的 MagicNumber 的定单。

范例 2: 在客户端内两个不同计算方法的智能交易同时运行。
任务: 智能交易只管理自己的定单。.
解决: 当开仓时，每个智能交易必须使用自己的 MagicNumber（零除外）。接下来的日子里，智能交易只会管理提前设定的MagicNumber的定单。

范例 3: 在客户端内几个智能交易，交易者和协助智能交易执行的不标准追踪止损同时运行。
任务: 交易的智能交易必须按照自己的形式计算，并且不干涉手动开仓。协助智能交易执行的追踪止损可以在手动开仓处修改，但是其他智能交易不能够开仓。
解决: 智能交易必须使用独有的MagicNumbers并且管理自己的仓位。协助智能交易修改的这些仓位，其 MagicNumber等于 0。

以上三个范例都很现实，用户可以提前解决问题。在这三个范例情况中，都是使用MagicNumber来解决问题的。这不是唯一解决问题的途径，但是最简单的途径。

3. 实践

现在让我们来解决特殊的任务:创建智能交易只管理自己的仓位，不理睬手动仓位和其他智能交易。

首先我们编写一个简单的智能交易，当 MACD 指标零线时，智能交易得到信号开仓。智能交易将会运行如下:

1. int start()
   
2. {
   
3.     //---- 记住将要分析的指标值
   
4.     //---- 注意：我们使用第一个和第二个柱。可以是每日的 1-bar 。
   
5.     //---- (即., 信号晚些显现), 但是保护反复开仓和平仓
   
6.     //---- 在柱内仓位的
   
7.     double MACD_1 = iMACD( Symbol(), 0, 12, 26, 9, PRICE_CLOSE, MODE_MAIN, 1 );
   
8.     double MACD_2 = iMACD( Symbol(), 0, 12, 26, 9, PRICE_CLOSE, MODE_MAIN, 2 );
   
9. 
   
10.     int _GetLastError = 0, _OrdersTotal = OrdersTotal();
    
11.     //---- 在开仓中搜索
    
12.     for ( int z = _OrdersTotal - 1; z >= 0; z -- )
    
13.     {
    
14.         //---- 如果在选择仓位中生成错误，转到下一步
    
15.         if ( !OrderSelect( z, SELECT_BY_POS ) )
    
16.         {
    
17.             _GetLastError = GetLastError();
    
18.             Print( "OrderSelect( ", z, ", SELECT_BY_POS ) - Error #", _GetLastError );
    
19.             continue;
    
20.         }
    
21. 
    
22.         //---- 如果开仓不是当前货币对，略过
    
23.         if ( OrderSymbol() != Symbol() ) continue;
    
24. 
    
25.         //---- 如果开仓为BUY,
    
26.         if ( OrderType() == OP_BUY )
    
27.         {
    
28.             //---- 如果 MACD指标看到的零线从上至下,
    
29.             if ( NormalizeDouble( MACD_1, Digits + 1 ) <  0.0 &&
    
30.                   NormalizeDouble( MACD_2, Digits + 1 ) >= 0.0    )
    
31.             {
    
32.                 //---- 平仓
    
33.                 if ( !OrderClose( OrderTicket(), OrderLots(), Bid, 5, Green ) )
    
34.                 {
    
35.                     _GetLastError = GetLastError();
    
36.                     Alert( "错误 OrderClose # ", _GetLastError );
    
37.                     return(-1);
    
38.                 }
    
39.             }
    
40.             //---- 如果警报没有改变,退出: 开仓尚早
    
41.             else return(0);
    
42.         }
    
43.         //---- 如果开仓位SELL,
    
44.         if ( OrderType() == OP_SELL )
    
45.         {
    
46.             //----如果MACD指标看到零线从下到上,
    
47.             if ( NormalizeDouble( MACD_1, Digits + 1 ) >  0.0 &&
    
48.                   NormalizeDouble( MACD_2, Digits + 1 ) <= 0.0    )
    
49.             {
    
50.                 //---- 平仓
    
51.                 if ( !OrderClose( OrderTicket(), OrderLots(), Ask, 5, Red ) )
    
52.                 {
    
53.                     _GetLastError = GetLastError();
    
54.                     Alert( "错误 OrderClose # ", _GetLastError );
    
55.                     return(-1);
    
56.                 }
    
57.             }
    
58.             //---- 如果警报没有改变,退出:开仓尚早
    
59.             else return(0);
    
60.         }
    
61.     }
    
62. 
    
63. //+------------------------------------------------------------------+
    
64. //| 如果达到此点,没有仓位开仓　　　　　　　　　　　　　　　　　　　　　　　　　   |
    
65. //| 检测是否仍有开仓的可能　　　　　　　　　　　　　　　　　　　　　　            |
    
66. //+------------------------------------------------------------------+
    
67. 
    
68.     //---- 如果MACD 指标看到零线从下到上,
    
69.     if ( NormalizeDouble( MACD_1, Digits + 1 ) >  0.0 &&
    
70.           NormalizeDouble( MACD_2, Digits + 1 ) <= 0.0    )
    
71.     {
    
72.         //---- 开BUY仓
    
73.         if ( OrderSend( Symbol(), OP_BUY, 0.1, Ask, 5, 0.0, 0.0, "MACD_test", 0, 0, Green ) < 0 )
    
74.         {
    
75.             _GetLastError = GetLastError();
    
76.             Alert( "错误OrderSend # ", _GetLastError );
    
77.             return(-1);
    
78.         }
    
79.         return(0);
    
80.     }
    
81.     //----如果MACD 指标看到零线从上至下,
    
82.     if ( NormalizeDouble( MACD_1, Digits + 1 ) <  0.0 &&
    
83.           NormalizeDouble( MACD_2, Digits + 1 ) >= 0.0    )
    
84.     {
    
85.         //---- 开 SELL 仓
    
86.         if ( OrderSend( Symbol(), OP_SELL, 0.1, Bid, 5, 0.0, 0.0, "MACD_test", 0, 0, Red ) < 0 )
    
87.         {
    
88.             _GetLastError = GetLastError();
    
89.             Alert( "错误OrderSend # ", _GetLastError );
    
90.             return(-1);
    
91.         }
    
92.         return(0);
    
93.     }
    
94. 
    
95.     return(0);
    
96. }

复制代码

我们将按照以下方法让它管理自己的仓位:

• 以Expert_ID　命名添加外部变量协助智能交易开仓来改变 MagicNumber 值
• 在函数OrderSelect()选择仓位之后，对编译Expert_ID变量所选定单的MagicNumber 添加检测
• 在开仓期间，我们将在MagicNumber处写下 Expert_ID的值替换 0
  

考虑上面的变化，代码将显现如下:

1. extern int Expert_ID = 1234;
   
2. 
   
3. int start()
   
4. {
   
5.     //---- 记住将要分析的指标值
   
6.     //---- 注意：我们使用第一个和第二个柱。可以是每日的 1-bar 。
   
7.     //---- (即., 信号晚些显现), 但是保护反复开仓和平仓
   
8.     //---- 在柱内仓位的
   
9.     double MACD_1 = iMACD( Symbol(), 0, 12, 26, 9, PRICE_CLOSE, MODE_MAIN, 1 );
   
10.     double MACD_2 = iMACD( Symbol(), 0, 12, 26, 9, PRICE_CLOSE, MODE_MAIN, 2 );
    
11. 
    
12.     int _GetLastError = 0, _OrdersTotal = OrdersTotal();
    
13.     //---- 在全部开仓中搜索
    
14.     for ( int z = _OrdersTotal - 1; z >= 0; z -- )
    
15.     {
    
16.         //---- 如果在搜索仓位中生成错误。转到下一步
    
17.         if ( !OrderSelect( z, SELECT_BY_POS ) )
    
18.         {
    
19.             _GetLastError = GetLastError();
    
20.             Print( "OrderSelect( ", z, ", SELECT_BY_POS ) -错误 #", _GetLastError );
    
21.             continue;
    
22.         }
    
23. 
    
24.         //---- 如果平仓仓位不是当前货币对，略过
    
25.         if ( OrderSymbol() != Symbol() ) continue;
    
26. 
    
27.         //---- 如果MagicNumber 不等于Expert_ID, 忽略此仓位
    
28.         if ( OrderMagicNumber() != Expert_ID ) continue;
    
29. 
    
30.         //---- 如果开BUY仓,
    
31.         if ( OrderType() == OP_BUY )
    
32.         {
    
33.             //---- 如果MACD 指标看到零线从上到下,
    
34.             if ( NormalizeDouble( MACD_1, Digits + 1 ) <  0.0 &&
    
35.                   NormalizeDouble( MACD_2, Digits + 1 ) >= 0.0    )
    
36.             {
    
37.                 //---- 平仓
    
38.                 if ( !OrderClose( OrderTicket(), OrderLots(), Bid, 5, Green ) )
    
39.                 {
    
40.                     _GetLastError = GetLastError();
    
41.                     Alert( "错误 OrderClose # ", _GetLastError );
    
42.                     return(-1);
    
43.                 }
    
44.             }
    
45.             //---- 如果警报没有改变, 退出: 开仓尚早
    
46.             else
    
47.             { return(0); }
    
48.         }
    
49.         //---- 如果开SELL仓,
    
50.         if ( OrderType() == OP_SELL )
    
51.         {
    
52.             //---- 如果MACD指标看到零线从下到上,
    
53.             if ( NormalizeDouble( MACD_1, Digits + 1 ) >  0.0 &&
    
54.                   NormalizeDouble( MACD_2, Digits + 1 ) <= 0.0    )
    
55.             {
    
56.                 //---- 平仓
    
57.                 if ( !OrderClose( OrderTicket(), OrderLots(), Ask, 5, Red ) )
    
58.                 {
    
59.                     _GetLastError = GetLastError();
    
60.                     Alert( "错误 OrderClose № ", _GetLastError );
    
61.                     return(-1);
    
62.                 }
    
63.             }
    
64.             //---- 如果警报没有改变,退出: 开仓尚早
    
65.             else return(0);
    
66.         }
    
67.     }
    
68. 
    
69. //+------------------------------------------------------------------+
    
70. //| 如果执行达到此点,没有仓位开仓　　　　　　　　　　　　　　　　　　　　　　    |
    
71. //| 检测是否有可能开仓　　　　　　　　　　　　　　　　　　　　　　　            |
    
72. //+------------------------------------------------------------------+
    
73. 
    
74.     //---- 如果MACD 指标看到零线从下到上,
    
75.     if ( NormalizeDouble( MACD_1, Digits + 1 ) >  0.0 &&
    
76.           NormalizeDouble( MACD_2, Digits + 1 ) <= 0.0    )
    
77.     {
    
78.         //---- 开BUY仓
    
79.         if ( OrderSend( Symbol(), OP_BUY, 0.1, Ask, 5, 0.0, 0.0, "MACD_test",
    
80.               Expert_ID, 0, Green ) < 0 )
    
81.         {
    
82.             _GetLastError = GetLastError();
    
83.             Alert( "错误OrderSend # ", _GetLastError );
    
84.             return(-1);
    
85.         }
    
86.         return(0);
    
87.     }
    
88.     //---- 如果MACD 指标看到零线从上至下,
    
89.     if ( NormalizeDouble( MACD_1, Digits + 1 ) <  0.0 &&
    
90.           NormalizeDouble( MACD_2, Digits + 1 ) >= 0.0    )
    
91.     {
    
92.         //---- 开SELL仓
    
93.         if ( OrderSend( Symbol(), OP_SELL, 0.1, Bid, 5, 0.0, 0.0, "MACD_test",
    
94.               Expert_ID, 0, Red ) < 0 )
    
95.         {
    
96.             _GetLastError = GetLastError();
    
97.             Alert( "错误 OrderSend # ", _GetLastError );
    
98.             return(-1);
    
99.         }
    
100.         return(0);
     
101.     }
     
102. 
     
103.     return(0);
     
104. }

复制代码

现在，当智能交易运行时，用户可以手动开仓。智能交易将不会干涉。

4. 多个相同的智能交易在一种货币对的不同图表上

存在这样的状况，相同的智能交易必须在相同货币对的图表中运行，但是需要不同的时间周期。例如，如果我们尝试添加我们的智能交易同时添加到 EURUSD, H1图表和 EURUSD, M30图表，他们将会相互影响:每个都会“考虑”开仓并且会默认管理。

这个问题可以通过 Expert_ID　一个协调另一个的方式解决。但是这羊不是很方便。如果很多智能交易在运行，他们的ID必然会混乱。

解决这个问题我们需要以 MagicNumber　值作为图表周期。怎样执行呢？如果我们添加图表周期到 Expert_ID, 可能２个不同的智能交易在２个不同的图表上生成相同的 MagicNumber。

所以我们最好用 Expert_ID值乘以 10 并且把图表周期(代码从1 到 9, 精确值)放置到最后  。

如下图表:

1. int Period_ID = 0;
   
2.     switch ( Period() )
   
3.     {
   
4.         case PERIOD_MN1: Period_ID = 9; break;
   
5.         case PERIOD_W1:  Period_ID = 8; break;
   
6.         case PERIOD_D1:  Period_ID = 7; break;
   
7.         case PERIOD_H4:  Period_ID = 6; break;
   
8.         case PERIOD_H1:  Period_ID = 5; break;
   
9.         case PERIOD_M30: Period_ID = 4; break;
   
10.         case PERIOD_M15: Period_ID = 3; break;
    
11.         case PERIOD_M5:  Period_ID = 2; break;
    
12.         case PERIOD_M1:  Period_ID = 1; break;
    
13.     }
    
14.     _MagicNumber = Expert_ID * 10 + Period_ID;

复制代码

现在添加这个代码智能交易的 init()函数并且用 Expert_ID替换MagicNumber。

最终版本的智能交易如下:

1. extern int Expert_ID = 1234;
   
2. int _MagicNumber = 0;
   
3. 
   
4. int init()
   
5. {
   
6.     int Period_ID = 0;
   
7.     switch ( Period() )
   
8.     {
   
9.         case PERIOD_MN1: Period_ID = 9; break;
   
10.         case PERIOD_W1:  Period_ID = 8; break;
    
11.         case PERIOD_D1:  Period_ID = 7; break;
    
12.         case PERIOD_H4:  Period_ID = 6; break;
    
13.         case PERIOD_H1:  Period_ID = 5; break;
    
14.         case PERIOD_M30: Period_ID = 4; break;
    
15.         case PERIOD_M15: Period_ID = 3; break;
    
16.         case PERIOD_M5:  Period_ID = 2; break;
    
17.         case PERIOD_M1:  Period_ID = 1; break;
    
18.     }
    
19.     _MagicNumber = Expert_ID * 10 + Period_ID;
    
20. 
    
21.     return(0);
    
22. }
    
23. 
    
24. int start()
    
25. {
    
26.     //---- 记住将要分析的指标值
    
27.     //---- 注意：我们使用第一个和第二个柱。可以是每日的 1-bar 。
    
28.     //---- (即., 信号晚些显现), 但是保护反复开仓和平仓
    
29.     //---- 在柱内仓位的
    
30.     double MACD_1 = iMACD( Symbol(), 0, 12, 26, 9, PRICE_CLOSE, MODE_MAIN, 1 );
    
31.     double MACD_2 = iMACD( Symbol(), 0, 12, 26, 9, PRICE_CLOSE, MODE_MAIN, 2 );
    
32. 
    
33.     int _GetLastError = 0, _OrdersTotal = OrdersTotal();
    
34.     //---- 在全部开仓中搜索
    
35.     for ( int z = _OrdersTotal - 1; z >= 0; z -- )
    
36.     {
    
37.         //---- 如果在搜索过程中生成错误。转到下一步
    
38.         if ( !OrderSelect( z, SELECT_BY_POS ) )
    
39.         {
    
40.             _GetLastError = GetLastError();
    
41.             Print( "OrderSelect( ", z, ", SELECT_BY_POS ) - 错误#", _GetLastError );
    
42.             continue;
    
43.         }
    
44. 
    
45.         //---- 如果开仓仓位不是当前货币对，忽略
    
46.         if ( OrderSymbol() != Symbol() ) continue;
    
47. 
    
48.         //---- 如果MagicNumber 不等于 _MagicNumber, 忽略此仓位
    
49.         if ( OrderMagicNumber() != _MagicNumber ) continue;
    
50. 
    
51.         //----如果开BUY仓,
    
52.         if ( OrderType() == OP_BUY )
    
53.         {
    
54.             //---- 如果MACD指标看见零线从上至下,
    
55.             if ( NormalizeDouble( MACD_1, Digits + 1 ) <  0.0 &&
    
56.                   NormalizeDouble( MACD_2, Digits + 1 ) >= 0.0    )
    
57.             {
    
58.                 //---- 平仓
    
59.                 if ( !OrderClose( OrderTicket(), OrderLots(), Bid, 5, Green ) )
    
60.                 {
    
61.                     _GetLastError = GetLastError();
    
62.                     Alert( "错误 OrderClose # ", _GetLastError );
    
63.                     return(-1);
    
64.                 }
    
65.             }
    
66.             //---- 如果警报没有改变，停止: 开新仓位尚早
    
67.             else return(0);
    
68.         }
    
69.         //---- 如果开SELL仓，
    
70.         if ( OrderType() == OP_SELL )
    
71.         {
    
72.             //---- 如果MACD指标看见零线从下到上,
    
73.             if ( NormalizeDouble( MACD_1, Digits + 1 ) >  0.0 &&
    
74.                   NormalizeDouble( MACD_2, Digits + 1 ) <= 0.0    )
    
75.             {
    
76.                 //----平仓
    
77.                 if ( !OrderClose( OrderTicket(), OrderLots(), Ask, 5, Red ) )
    
78.                 {
    
79.                     _GetLastError = GetLastError();
    
80.                     Alert( "错误OrderClose № ", _GetLastError );
    
81.                     return(-1);
    
82.                 }
    
83.             }
    
84.             //---- 如果警报没有改变, 停止: 开新仓位尚早
    
85.             else return(0);
    
86.         }
    
87.     }
    
88. 
    
89. //+------------------------------------------------------------------+
    
90. //| 如果执行达到此点，没有仓位开仓　　　　　　　　　　　　　　　　　　　　　　    |
    
91. //| 检测是否仍有可能开仓　　　　　　　　　　　　　　　　　　　　　　　           |
    
92. //+------------------------------------------------------------------+
    
93. 
    
94.     //---- 如果MACD 指标看见零线从下到上,
    
95.     if ( NormalizeDouble( MACD_1, Digits + 1 ) >  0.0 &&
    
96.           NormalizeDouble( MACD_2, Digits + 1 ) <= 0.0    )
    
97.     {
    
98.         //---- 开 BUY 仓
    
99.         if ( OrderSend( Symbol(), OP_BUY, 0.1, Ask, 5, 0.0, 0.0, "MACD_test",
    
100.               _MagicNumber, 0, Green ) < 0 )
     
101.         {
     
102.             _GetLastError = GetLastError();
     
103.             Alert( "错误 OrderSend # ", _GetLastError );
     
104.             return(-1);
     
105.         }
     
106.         return(0);
     
107.     }
     
108.     //---- 如果MACD 指标看到零线从上至下,
     
109.     if ( NormalizeDouble( MACD_1, Digits + 1 ) <  0.0 &&
     
110.           NormalizeDouble( MACD_2, Digits + 1 ) >= 0.0    )
     
111.     {
     
112.         //---- 开 SELL 仓
     
113.         if ( OrderSend( Symbol(), OP_SELL, 0.1, Bid, 5, 0.0, 0.0, "MACD_test",
     
114.               _MagicNumber, 0, Red ) < 0 )
     
115.         {
     
116.             _GetLastError = GetLastError();
     
117.             Alert( "错误 OrderSend # ", _GetLastError );
     
118.             return(-1);
     
119.         }
     
120.         return(0);
     
121.     }
     
122. 
     
123.     return(0);
     
124. }

复制代码

这样的显示智能交易可以在不同周期的几个图表中使用。

如果需要在相同时间周期和货币对的图表(例如, EURUSD H1 和EURUSD H4)上开启两个智能交易， 此Expert_ID 变量值将被改变。但是这种情况很罕见。

使用以上代码，用户能够改善他的智能交易并且“教会”智能交易区分自己的仓位和他人的仓位。